Программа

'Вычисление интеграла методом Симпсона
DECLARE FUNCTION Integral! (Left!, Right!, Break%)

DEF FNFun! (X!) = X!  'Вычисление интегрируемой функции

'Ввод данных:
INPUT "Введите левую границу интервала интегрирования ", Left!
INPUT "Введите правую границу интервала интегрирования ", Right!
INPUT "Введите разбиение интервала интегрирования ", Break%

PRINT "="; Integral!(Left!, Right!, Break%)   'Вычисление и вывод результата
END

FUNCTION Integral! (Left!, Right!, Break%) 'Вычисление интеграла
  LengthStep! = (Right! - Left!) / Break% / 2
                                     'Вычисление длины шага интегрирования
  X! = Left! + LengthStep!  'Начальное определение промежуточной абсциссы
  Sum1! = 0      'Обнуление промежуточной суммы 1
  Sum2! = FNFun!(X!)    'Начальное определение промежуточной суммы 2
  FOR i% = 2 TO Break%     'Цикл набора промежуточных сумм
    X! = X! + LengthStep!    'Переопределение абсциссы
    Sum1! = Sum1! + FNFun!(X!)   'Набор промежуточной суммы 1
    X! = X! + LengthStep!   'Переопределение абсциссы
    Sum2! = Sum2! + FNFun!(X!)   'Набор промежуточной суммы 2
  NEXT i%
  Integral! = LengthStep! / 3 * (FNFun!(Left!) + FNFun!(Right!) + 2 * Sum1! + 4 * Sum2!)
                                             'Определение значения интеграла
END FUNCTION