Программа

' Вычисление интеграла
' методом прямоугольников

DEF FNFun! (X!) = X! * X!   'Вычисление интегрируемой функции

DEF FNIntegral! (Left!, Right!, Break%) 'Вычисление интеграла
  Sum! = 0   'Обнуление промежуточной суммы
  LengthStep! = (Right! - Left!) / Break%
                                    'Вычисление длины шага интегрирования
  PointX! = Left! + .5 * LengthStep!
                               'Вычисление абсциссы средины левого промежутка
  FOR i% = 1 TO Break%           'Цикл набора промежуточной суммы
    Sum! = Sum! + FNFun!(PointX!)  'Набор промежуточной суммы
    PointX! = PointX! + LengthStep!
                             'Пересчет абсциссы средины следующего промежутка
  NEXT i%
  FNIntegral! = Sum! * LengthStep!  'Определение интегральной суммы
END DEF

'----------------------------------------------------------------------------

'Ввод данных:
INPUT "Введите левую границу интервала интегрирования ", Left!
INPUT "Введите правую границу интервала интегрирования ", Right!
INPUT "Введите разбиение интервала интегрирования ", Break%

PRINT "="; FNIntegral!(Left!, Right!, Break%)   'Вычисление и вывод результата
END