Программа

TYPE RefType=^NumType; { Тип - ссылка на число }
     NumType=record { Тип - число }
               Num:integer;
               Next:RefType
             end;
VAR F_In,F_Out:text;  { Файловые переменные }
    FileNameIn,FileNameOut:string;
    Ref,List:RefType; { Ссылки на элемент и список }
BEGIN
  WriteLn; { Пропуск строки }
  Write('Введите имя входного файла: '); { Вывод приглашения }
  ReadLn(FileNameIn);  { Ввод имени входного файла }
  Write('Введите имя выходного файла: '); { Вывод приглашения }
  ReadLn(FileNameOut);  { Ввод имени выходного файла }
  { Связывание файловых переменных: }
  Assign(F_In,FileNameIn);
  Assign(F_Out,FileNameOut);
  Reset(F_In);  { Открытие файла }
  List:=nil;  { Сброс ссылки }
  while not EOF(F_In) do  { Цикл чтения файла }
  Begin
    New(Ref);  { Создание переменной }
    ReadLn(F_In,Ref^.Num); { Чтение числа }
    Ref^.Next:=List;  { Присоединение списка }
    List:=Ref   { Переопределение ссылки на спискок }
  End;
  Close(F_In); { Закрытие файла }
  Rewrite(F_Out);   { Открытие файла }
  while List<>nil do { Цикл вывода списка }
  Begin
    WriteLn(F_Out,List^.Num);  { Вывод числа в файл }
    Ref:=List;  { Сохранение ссылки на первый элемент списка }
    List:=List^.Next; { Переопределение ссылки на список }
    Dispose(Ref)  { Уничтожение переменной }
  End;
  Close(F_Out) { Закрытие файла }
END.