Программа

PROGRAM Rectangle;
FUNCTION F(X:real):real;far; { Вычисление интегрируемой функции }
  Begin
    F:=x*Exp(Ln(X-1)/3)
  End;
FUNCTION Integral(Left,Right:real;Break:integer):real;
                                              { Функция вычисления интеграла }
  Var Sum,                                    { Промежуточная сумма }
      LengthStep,                             { Длина шага разбиения }
      LeftY,RightX,             { Левая и правая границы шага интегрирования }
      PointX,                   { Абсцисса средины левого промежутка }
      RightY:real;              { Значение интегрируемой функции
                                  на правой границе шага интегрирования }
      i:integer;                { Счетчик }
  Begin
    Sum:=0;  { Обнуление промежуточной суммы }
    LengthStep:=(Right-Left)/Break; { Вычисление длины шага интегрирования }
    PointX:=Left+0.5*LengthStep;
                             { Вычисление абсциссы средины левого промежутка }
    for i:=1 to Break do       { Цикл набора промежуточной суммы }
      begin
        Sum:=Sum+F(PointX);  { Набор промежуточной суммы }
        PointX:=PointX+LengthStep
                           { Пересчет абсциссы средины следующего промежутка }
      end;
    Integral:=Sum*LengthStep { Определение интегральной суммы }
  End;
VAR StepBreak:integer;  { Шаг изменения разбиения }
    i:integer; { Счетчик цикла }
    Left,Right:real;       { Левая и правая границы интервала интегрирования }
BEGIN
{ Ввод данных: }
  Write('Введите левую границу интервала интегрирования ');
  ReadLn(Left);
  Write('Введите правую границу интервала интегрирования ');
  ReadLn(Right);
  WriteLn('╔═════╦════════════════════╗');
  WriteLn('║  n  ║ Значение интеграла ║');
  WriteLn('╠═════╬════════════════════╣');
  for i:=1 to 5 do
  WriteLn('║ ',i*30:3,' ║ ',Integral(Left,Right,i*30),'  ║');
                                          { Вычисление и вывод результата }
  WriteLn('╚═════╩════════════════════╝')
END.