Программа

'Описание массива:
Lin% = 5
Column% = 6
DIM A(Lin%, Column%)

'Ввод границ и шага X:
CLS 'Очистка экрана
INPUT "Введите StartX=", StartX
INPUT "Введите EndX=", EndX
INPUT "Введите StepX=", StepX

CLS 'Очистка экрана
FOR i% = 1 TO Lin%     'Цикл инициализации строк массива A
  FOR j% = 1 TO Column%   'Цикл инициализации элементов массива A
    PRINT USING "Введите элемент A[#;#] "; i%; j%;
                                    'Вывод приглашения ввести элемент массива T
    INPUT "", A(i%, j%)   'Ввод элемента массива
  NEXT j%
NEXT i%

CLS 'Очистка экрана
PRINT "Массив A:"   'Вывод заголовка
FOR i% = 1 TO Lin%    'Цикл вывода строк массива A
  FOR j% = 1 TO Column%   'Цикл вывода элементов массива A
    PRINT USING " ##.# "; A(i%, j%); 'Вывод элемента массива A
  NEXT j%
  PRINT 'Вывод конца строки
NEXT i%
PRINT 'Пропуск строки

a1 = 0: a2 = 1: a3 = 0: a4 = 1: a5 = 0: a6 = 1
                                           'Начальное определение коэффициентов
FOR i% = 1 TO Lin%     'Цикл просмотра строк массива A
  FOR j% = 1 TO Column%    'Цикл просмотра элементов массива A
    'Обработка элемента массива A:
    IF A(i%, j%) > 0 THEN
                       a1 = a1 + A(i%, j%) 'Набор суммы положительных элементов
                       a2 = a2 * A(i%, j%)
                                    'Набор произведения положительных элементов
    END IF
    IF A(i%, j%) < 0 THEN
                       a3 = a3 + A(i%, j%) 'Набор суммы отрицательных элементов
                       a4 = a4 * A(i%, j%)
                                    'Набор произведения отрицательных элементов
    END IF
    a5 = a5 + A(i%, j%)  'Набор суммы всех элементов
    a6 = a6 * A(i%, j%)  'Набор произведения всех элементов
  NEXT j%
NEXT i%

'Вывод коэффициентов:
PRINT "Kоэффициенты:" 'Вывод заголовка
PRINT USING "a1=###.##^^^^     a2=###.##^^^^"; a1; a2
PRINT USING "a3=###.##^^^^     a4=###.##^^^^"; a3; a4
PRINT USING "a5=###.##^^^^     a6=###.##^^^^"; a5; a6
PRINT 'Пропуск строки

'Начальное определение наименьших значений многочлена и производной:
MinP5 = ((((a1 * StartX + a2) * StartX + a3) * StartX + a4) * StartX + a5) * StartX + a6
MinP5Derivate = (5 * 4 * 3 * a1 * StartX + 4 * 3 * 2 * a2) * StartX + 3 * 2 * a3

FOR i% = 0 TO CINT((EndX - StartX) / StepX)  'Цикл перебора значений X
  X = StartX + i% * StepX 'Определение  значения X
  P5 = ((((a1 * X + a2) * X + a3) * X + a4) * X + a5) * X + a6
                                                         'Вычисление многочлена
  P5Derivate = (5 * 4 * 3 * a1 * X + 4 * 3 * 2 * a2) * X + 3 * 2 * a3
                                                        'Вычисление проиэводной
  PRINT USING "P5(##.##)=###.##^^^^   P5'''(##.##)=###.##^^^^"; X; P5; X; P5Derivate
                                       'Вывод значений многочлена и проиэводной
  IF P5 < MinP5 THEN MinP5 = P5
                              'Переопределение минимального значения многочлена
  IF P5Derivate < MinP5Derivate THEN MinP5Derivate = P5Derivate
                             'Переопределение минимального значения производной
NEXT i%

PRINT 'Пропуск строки
PRINT USING "MinP5=###.##^^^^       MinP5'''=###.##^^^^"; MinP5; MinP5Derivate
                           'Вывод минимальных значений многочлена и проиэводной
END